<'
#                                           Anthony Mallet on Wed Aug  6 2025
#
args component ifaces

# compute handy shortcuts
set comp [string map {- _} [$component name]]
set rospkg [rospkg $component]
'>
# CMakeLists.txt for <"$rospkg">
#
cmake_minimum_required(VERSION 3.15)
project(<"$rospkg">)

set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)

# generate interfaces
find_package(ament_cmake REQUIRED)
find_package(rosidl_default_generators REQUIRED)

rosidl_generate_interfaces(${PROJECT_NAME}
  "<"[join [lmap i $ifaces {string cat ../ $i}] "\"\n  \""]">")

ament_package()


# targets for building only the required bits for genom components
rosidl_get_typesupport_target(genc <"$rospkg"> rosidl_generator_c)
rosidl_get_typesupport_target(ts <"$rospkg"> rosidl_typesupport_c)

add_custom_target(genom-<"$comp">-typesupport)
add_dependencies(genom-<"$comp">-typesupport ${genc} ${ts})


# export ros configuration for autoconf
find_package(rcutils 6 REQUIRED)
find_package(rcl 9 REQUIRED)
find_package(rcl_action 9 REQUIRED)
find_package(rmw 7 REQUIRED)
find_package(rosidl_runtime_c 4 REQUIRED)
find_package(fastcdr 2 REQUIRED)
set(common_deps
  rcutils::rcutils
  rcl::rcl
  rcl_action::rcl_action
  rosidl_runtime_c::rosidl_runtime_c
  fastcdr)
set(client_deps
  ${common_deps})
set(server_deps
  ${common_deps}
  rmw::rmw)

macro(xjoin var str)
  set(${var} "$<REMOVE_DUPLICATES:${${var}}>")
  set(${var} "$<$<BOOL:${${var}}>:${str}$<JOIN:${${var}}, ${str}>>")
endmacro()

foreach(c "client" "server")
  set(config_DEFINES "$<TARGET_PROPERTY:${ts},INTERFACE_COMPILE_DEFINITIONS>")
  set(config_INCLUDES "$<TARGET_PROPERTY:${ts},INTERFACE_INCLUDE_DIRECTORIES>")
  set(config_LDFLAGS "${CMAKE_INSTALL_PREFIX}/lib")
  set(config_LIBS
    "-L$<TARGET_LINKER_FILE_DIR:${ts}>"
    "-l$<TARGET_LINKER_FILE_BASE_NAME:${ts}>"
    "-L$<TARGET_LINKER_FILE_DIR:${genc}>"
    "-l$<TARGET_LINKER_FILE_BASE_NAME:${genc}>")
  foreach(d IN LISTS ${c}_deps)
    list(APPEND config_DEFINES
      "$<TARGET_PROPERTY:${d},INTERFACE_COMPILE_DEFINITIONS>")
    list(APPEND config_INCLUDES
      "$<TARGET_PROPERTY:${d},INTERFACE_INCLUDE_DIRECTORIES>")
    list(APPEND config_LDFLAGS "$<TARGET_LINKER_FILE_DIR:${d}>")
    string(REGEX REPLACE "::.*" "" base ${d})
    list(APPEND config_LIBS "-L$<TARGET_LINKER_FILE_DIR:${d}>" "-l${base}")
  endforeach()

  xjoin(config_DEFINES "-D")
  xjoin(config_INCLUDES "-I")
  xjoin(config_LDFLAGS "-R")
  xjoin(config_LIBS "")

  set(config
    "ROS_CPPFLAGS='${config_DEFINES} ${config_INCLUDES}'"
    "ROS_LDFLAGS='${config_LDFLAGS}'"
    "ROS_LIBS='${config_LIBS}'")
  file(GENERATE OUTPUT ros-${c}-config.sh CONTENT "$<JOIN:${config},\n>")
endforeach()


# uninstall (renamed to avoid conflict with the ament uninstall target,
# which does not support DESTDIR and leaves .pyc files behind).
#
add_custom_target(deinstall
  COMMAND /bin/sh -c
  "for d in . action msg srv; do rm -vrf -- \"$DESTDIR$1/$d/__pycache__\"; done"
  sh "${CMAKE_INSTALL_PREFIX}/${PYTHON_INSTALL_DIR}/${PROJECT_NAME}"
  COMMAND /bin/sh -c "							\
    test ! -f \"$1\" || while IFS= read -r f || test -n \"$f\"; do	\
      f=$DESTDIR$f; rm -vrf \"$f\";					\
      while test -n \"$f\"; do						\
        f=\${f%/*}; rmdir \"$f\" 2>/dev/null || break;			\
        echo removed \"$f\";						\
      done;								\
    done <\"$1\""
  sh "${CMAKE_BINARY_DIR}/install_manifest.txt"
  VERBATIM)
